Re: Erstellen eines diskreten Datensatzes aus experimentellen Daten

[Hakan Önel <honel@XXXXXXX.de>]

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA512 

Hallo, 

ich denke man könnte folgendermaßen mit MMA 6.0.1 verfahren: 

============================================================
Begin MMA 6.0.1 Block
============================================================ 

(* Löschung der Globalen Variablen, und Erzeugung eines Beispieldatensatzes
  bestehend aus 20 Punkten.*)
Remove["Global`*"];
height = Sort[RandomSample[Range[0, 40000], 20]] (*Meter*);
pressure = Sort[RandomSample[Range[950, 1050], 20]] (*Milli Bar*);
dataset = Thread[{height, pressure}] 

(* Erzeugung einer linearen Interpolation von den "dataset" genannten Daten 
*)
p[h_] := Interpolation[dataset, InterpolationOrder -> 1][h]; 

(* Diskretisierung der Funktion p[h], im Intervall [Min[height], 
Max[height]]
  mit einer 250 m Schrittweite. *)
disdataset=Table[{h,p[h]}, {h, Min[height], Max[height], 250}]
graph[1] = ListPlot[
           Map[Tooltip, N[dataset]],
           AxesLabel->{"height/m","pressure/(mBar)"},
           PlotRange->All
          ]
(* Darstellung der Interpolationsfunktion *)
graph[2] = Plot[
           p[h], {h, Min[height], Max[height]},
           AxesLabel->{"height/m","pressure/(mBar)"},
           PlotRange->All
          ] 

(* Überlagerung beider Plots *)
Show[Table[graph[i],{i,1,2}]] 

============================================================
End MMA 6.0.1 Block
============================================================ 

Ich hoffe das beantwortet die Frage? 

Viele Grüße 

Hakan 

- --
|
| Hakan Önel  (LaTeX: Hakan \"O{}nel)
| phone: +49-331-7499-397, fax: +49-1212-5-059-74-152
|
| Astrophysical Institute Potsdam (AIP)
| Solar Radio Physics, Room: B20/32,
| An der Sternwarte 16, 14482 Potsdam, Germany
|
- -- 


Marcel Bartlome schrieb:
> guten tag 
>
> ich bin ein blutiger anfänger in mathematica und habe nun folgende frage: 
>
> angenommen ich habe experimentell gemessene daten (ca 150 datenpunkte),
> in meinem fall höhe und druck, die nicht in genauen abständen gemessen
> wurden (von wetterballon).
> bsp:
> h1 = 0 m, p1 = 960mbar,
> h2 = 464m, p2 = ....
> :
> pn = 35569m, pn = ... 
>
> nun möchte ich aus diesen daten ein höhenprofil aufstellen, das den
> druck in regelmässigen abständen von zb 10 m angibt 
>
> bsp:
> h1 = 10m, p1 = ...
> h2 = 20m, p2 = ...
> :
> hn = 40000m, pn = ... 
>
> wie kann ich das machen?
> habe mit SplineFit oder Interpolation probiert, jedoch bin ich nicht auf
> etwas ansprechendes gekommen....
> in matlab gibt es eine funktion spline, die mir diese aufgabe in einer
> zeile löst! gibt es sowas in mathematica auch? für eure hilfe danke ich
> im voraus! 
>
> gruss marcel 
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.5 (GNU/Linux)
Comment: Using GnuPG with Mozilla - http://enigmail.mozdev.org 

iFcDBQFHDd43RF0kw+///F0RCozZAQCG+5PXdXbZIU/ph1lmdYxeRxY0V0sZ4XPr
jcHdVZD97gD/deKbQxaKFHGtMtt6S+dE746L7S+NqYzWTHUmKo7gmoo=
=/1S3
-----END PGP SIGNATURE-----