Re: Animation mit Mma 6

[Jens-Peer Kuska <kuska@XXXXXXX.de>]

Hallo,
das funktioniert sehr schön:

SinusPlot[Anzahl_] :=
Module[{K, Bogen, L1, L2, L3, Punkt, FPunkt, Schrittweite, T},
 Off[Plot::plln, Plot::plld, Show::gcomb];
 K[t_] = Circle[{-1, 0}, 1, {t, 2 Pi}];
 Bogen[t_] = Circle[{-1, 0}, 1, {0, t}];
 Punkt[t_] = Point[{-1 + Cos[t], Sin[t]}];
 L1[t_] := Line[{{-1 + Cos[t], Sin[t]}, {-1 + Cos[t], 0}}];
 L2[t_] := Line[{{0, 0}, {t, 0}}];
 L3[t_] = Line[{{t, 0}, {t, Sin[t]}}];
 FPunkt[t_] := Point[{t, Sin[t]}];
 Schrittweite = 2 Pi/(Anzahl - 1);
 Animate[
  GraphicsRow[{Plot[Sin[T], {T, 0, t + 0.00000001},
     PlotRange -> {{0, 2 Pi}, {-1, 1}}],
    Dynamic@
     Graphics[{RGBColor[1, 1, 1], Point[{2 Pi, 1.1}],
       Point[{2 Pi, -1.1}], RGBColor[0, 0, 0], K[t],
       RGBColor[1, 0, 0], Thickness[0.01], Bogen[t], L2[t],
       RGBColor[0, 0, 0], PointSize[0.02], Punkt[t], FPunkt[t],
       RGBColor[0, 1, 0], L1[t], L3[t]}]}], {t, 0, 2 Pi,
   Schrittweite}]]


Man muss aber bedenken, das Animate[] für die Zeitvariable ein neues Symbol
erzeugt, das nix mit einem vorher definierten t zu tun hat ..

Gruss
 Jens

heinrich@XXXXXXX.de wrote:
> Also genauer: Die folgende Animation zur Entstehung der Sinusfunktion lief seit
> Jahren erfolgreich:
>
> SinusPlot[Anzahl_] := 
>  Module[{K, Bogen, L1, L2, L3, FPunkt, Schrittweite, t, T},
>   Off[Plot::plln, Plot::plld, Show::gcomb];
>   K = Circle[{-1, 0}, 1, {t, 2 Pi}];
>   Bogen = Circle[{-1, 0}, 1, {0, t}];
>   
>   Punkt = Point[{-1 + Cos[t], Sin[t]}];
>   L1 = Line[{{-1 + Cos[t], Sin[t]}, {-1 + Cos[t], 0}}];
>   L2 = Line[{{0, 0}, {t, 0}}];
>   L3 = Line[{{t, 0}, {t, Sin[t]}}];
>   FPunkt = Point[{t, Sin[t]}];
>   Schrittweite = 2 Pi/(Anzahl - 1);
>   Animate[{Plot[Sin[T], {T, 0, t + 0.00000001}], 
>     Graphics[{RGBColor[1, 1, 1], Point[{2 Pi, 1.1}], 
>       Point[{2 Pi, -1.1}], RGBColor[0, 0, 0], K, RGBColor[1, 0, 0], 
>       Thickness[0.01], Bogen, L2, RGBColor[0, 0, 0], PointSize[0.02], 
>       Punkt, FPunkt, RGBColor[0, 1, 0], L1, L3}]}, {t, 0, 2 Pi, 
>     Schrittweite}]]
>
> Jetzt funktioniert das aber nicht mehr; das Gleiche gilt für die Entstehung von
> Zykloiden etc.
>
>
> MfG
> E. Heinrich
>
>
>